Theory Matrix_Sums

theory Matrix_Sums
  imports Hermitian_Functional_Calculus QHLProver.Matrix_Limit
begin

section ‹Finite sums of matrices›

text ‹For QHLProver's sums $\sum_{k<n}F_k$ of $K\times K$ matrices: entries are sums of entries, and a sum
of multiples of one matrix is a multiple of it,
\[ \Bigl(\sum_kF_k\Bigr)_{ij}=\sum_k(F_k)_{ij},\qquad \sum_kf_k\,B=\Bigl(\sum_kf_k\Bigr)B. \]›

lemma matrix_sum_index:
  assumes f: "⋀k. k < n ⟹ f k ∈ carrier_mat K K" and ij: "i < K" "j < K"
  shows "matrix_sum K f n $$ (i, j) = (∑k<n. f k $$ (i, j))"
  using f
proof (induction n)
  case (Suc n)
  have c: "matrix_sum K f n ∈ carrier_mat K K" by (rule matrix_sum_dim) (use Suc.prems in auto)
  have "matrix_sum K f (Suc n) $$ (i, j) = f n $$ (i, j) + matrix_sum K f n $$ (i, j)"
    using c Suc.prems[of n] ij by simp
  thus ?case using Suc by (simp add: add_ac)
qed (use ij in simp)

lemma matrix_sum_scalar:
  assumes B: "B ∈ carrier_mat d d"
  shows "matrix_sum d (λk. f k ⋅m B) m = (∑k<m. f k) ⋅m B"
proof (induction m)
  case 0 show ?case by (rule eq_matI) (use B in auto)
next
  case (Suc m)
  show ?case unfolding matrix_sum.simps Suc.IH using B by (intro eq_matI) (auto simp: algebra_simps)
qed

end