Theory Sublist

(*  Title:      HOL/Library/Sublist.thy
    Author:     Tobias Nipkow and Markus Wenzel, TU Muenchen
    Author:     Christian Sternagel, JAIST
*)

header {* List prefixes, suffixes, and homeomorphic embedding *}

theory Sublist
imports Main
begin

subsection {* Prefix order on lists *}

definition prefixeq :: "'a list => 'a list => bool"
  where "prefixeq xs ys <-> (∃zs. ys = xs @ zs)"

definition prefix :: "'a list => 'a list => bool"
  where "prefix xs ys <-> prefixeq xs ys ∧ xs ≠ ys"

interpretation prefix_order: order prefixeq prefix
  by default (auto simp: prefixeq_def prefix_def)

interpretation prefix_bot: bot prefixeq prefix Nil
  by default (simp add: prefixeq_def)

lemma prefixeqI [intro?]: "ys = xs @ zs ==> prefixeq xs ys"
  unfolding prefixeq_def by blast

lemma prefixeqE [elim?]:
  assumes "prefixeq xs ys"
  obtains zs where "ys = xs @ zs"
  using assms unfolding prefixeq_def by blast

lemma prefixI' [intro?]: "ys = xs @ z # zs ==> prefix xs ys"
  unfolding prefix_def prefixeq_def by blast

lemma prefixE' [elim?]:
  assumes "prefix xs ys"
  obtains z zs where "ys = xs @ z # zs"
proof -
  from `prefix xs ys` obtain us where "ys = xs @ us" and "xs ≠ ys"
    unfolding prefix_def prefixeq_def by blast
  with that show ?thesis by (auto simp add: neq_Nil_conv)
qed

lemma prefixI [intro?]: "prefixeq xs ys ==> xs ≠ ys ==> prefix xs ys"
  unfolding prefix_def by blast

lemma prefixE [elim?]:
  fixes xs ys :: "'a list"
  assumes "prefix xs ys"
  obtains "prefixeq xs ys" and "xs ≠ ys"
  using assms unfolding prefix_def by blast


subsection {* Basic properties of prefixes *}

theorem Nil_prefixeq [iff]: "prefixeq [] xs"
  by (simp add: prefixeq_def)

theorem prefixeq_Nil [simp]: "(prefixeq xs []) = (xs = [])"
  by (induct xs) (simp_all add: prefixeq_def)

lemma prefixeq_snoc [simp]: "prefixeq xs (ys @ [y]) <-> xs = ys @ [y] ∨ prefixeq xs ys"
proof
  assume "prefixeq xs (ys @ [y])"
  then obtain zs where zs: "ys @ [y] = xs @ zs" ..
  show "xs = ys @ [y] ∨ prefixeq xs ys"
    by (metis append_Nil2 butlast_append butlast_snoc prefixeqI zs)
next
  assume "xs = ys @ [y] ∨ prefixeq xs ys"
  then show "prefixeq xs (ys @ [y])"
    by (metis prefix_order.eq_iff prefix_order.order_trans prefixeqI)
qed

lemma Cons_prefixeq_Cons [simp]: "prefixeq (x # xs) (y # ys) = (x = y ∧ prefixeq xs ys)"
  by (auto simp add: prefixeq_def)

lemma prefixeq_code [code]:
  "prefixeq [] xs <-> True"
  "prefixeq (x # xs) [] <-> False"
  "prefixeq (x # xs) (y # ys) <-> x = y ∧ prefixeq xs ys"
  by simp_all

lemma same_prefixeq_prefixeq [simp]: "prefixeq (xs @ ys) (xs @ zs) = prefixeq ys zs"
  by (induct xs) simp_all

lemma same_prefixeq_nil [iff]: "prefixeq (xs @ ys) xs = (ys = [])"
  by (metis append_Nil2 append_self_conv prefix_order.eq_iff prefixeqI)

lemma prefixeq_prefixeq [simp]: "prefixeq xs ys ==> prefixeq xs (ys @ zs)"
  by (metis prefix_order.le_less_trans prefixeqI prefixE prefixI)

lemma append_prefixeqD: "prefixeq (xs @ ys) zs ==> prefixeq xs zs"
  by (auto simp add: prefixeq_def)

theorem prefixeq_Cons: "prefixeq xs (y # ys) = (xs = [] ∨ (∃zs. xs = y # zs ∧ prefixeq zs ys))"
  by (cases xs) (auto simp add: prefixeq_def)

theorem prefixeq_append:
  "prefixeq xs (ys @ zs) = (prefixeq xs ys ∨ (∃us. xs = ys @ us ∧ prefixeq us zs))"
  apply (induct zs rule: rev_induct)
   apply force
  apply (simp del: append_assoc add: append_assoc [symmetric])
  apply (metis append_eq_appendI)
  done

lemma append_one_prefixeq:
  "prefixeq xs ys ==> length xs < length ys ==> prefixeq (xs @ [ys ! length xs]) ys"
  unfolding prefixeq_def
  by (metis Cons_eq_appendI append_eq_appendI append_eq_conv_conj
    eq_Nil_appendI nth_drop')

theorem prefixeq_length_le: "prefixeq xs ys ==> length xs ≤ length ys"
  by (auto simp add: prefixeq_def)

lemma prefixeq_same_cases:
  "prefixeq (xs⇣1::'a list) ys ==> prefixeq xs⇣2 ys ==> prefixeq xs⇣1 xs⇣2 ∨ prefixeq xs⇣2 xs⇣1"
  unfolding prefixeq_def by (metis append_eq_append_conv2)

lemma set_mono_prefixeq: "prefixeq xs ys ==> set xs ⊆ set ys"
  by (auto simp add: prefixeq_def)

lemma take_is_prefixeq: "prefixeq (take n xs) xs"
  unfolding prefixeq_def by (metis append_take_drop_id)

lemma map_prefixeqI: "prefixeq xs ys ==> prefixeq (map f xs) (map f ys)"
  by (auto simp: prefixeq_def)

lemma prefixeq_length_less: "prefix xs ys ==> length xs < length ys"
  by (auto simp: prefix_def prefixeq_def)

lemma prefix_simps [simp, code]:
  "prefix xs [] <-> False"
  "prefix [] (x # xs) <-> True"
  "prefix (x # xs) (y # ys) <-> x = y ∧ prefix xs ys"
  by (simp_all add: prefix_def cong: conj_cong)

lemma take_prefix: "prefix xs ys ==> prefix (take n xs) ys"
  apply (induct n arbitrary: xs ys)
   apply (case_tac ys, simp_all)[1]
  apply (metis prefix_order.less_trans prefixI take_is_prefixeq)
  done

lemma not_prefixeq_cases:
  assumes pfx: "¬ prefixeq ps ls"
  obtains
    (c1) "ps ≠ []" and "ls = []"
  | (c2) a as x xs where "ps = a#as" and "ls = x#xs" and "x = a" and "¬ prefixeq as xs"
  | (c3) a as x xs where "ps = a#as" and "ls = x#xs" and "x ≠ a"
proof (cases ps)
  case Nil
  then show ?thesis using pfx by simp
next
  case (Cons a as)
  note c = `ps = a#as`
  show ?thesis
  proof (cases ls)
    case Nil then show ?thesis by (metis append_Nil2 pfx c1 same_prefixeq_nil)
  next
    case (Cons x xs)
    show ?thesis
    proof (cases "x = a")
      case True
      have "¬ prefixeq as xs" using pfx c Cons True by simp
      with c Cons True show ?thesis by (rule c2)
    next
      case False
      with c Cons show ?thesis by (rule c3)
    qed
  qed
qed

lemma not_prefixeq_induct [consumes 1, case_names Nil Neq Eq]:
  assumes np: "¬ prefixeq ps ls"
    and base: "!!x xs. P (x#xs) []"
    and r1: "!!x xs y ys. x ≠ y ==> P (x#xs) (y#ys)"
    and r2: "!!x xs y ys. [| x = y; ¬ prefixeq xs ys; P xs ys |] ==> P (x#xs) (y#ys)"
  shows "P ps ls" using np
proof (induct ls arbitrary: ps)
  case Nil then show ?case
    by (auto simp: neq_Nil_conv elim!: not_prefixeq_cases intro!: base)
next
  case (Cons y ys)
  then have npfx: "¬ prefixeq ps (y # ys)" by simp
  then obtain x xs where pv: "ps = x # xs"
    by (rule not_prefixeq_cases) auto
  show ?case by (metis Cons.hyps Cons_prefixeq_Cons npfx pv r1 r2)
qed


subsection {* Parallel lists *}

definition parallel :: "'a list => 'a list => bool"  (infixl "\<parallel>" 50)
  where "(xs \<parallel> ys) = (¬ prefixeq xs ys ∧ ¬ prefixeq ys xs)"

lemma parallelI [intro]: "¬ prefixeq xs ys ==> ¬ prefixeq ys xs ==> xs \<parallel> ys"
  unfolding parallel_def by blast

lemma parallelE [elim]:
  assumes "xs \<parallel> ys"
  obtains "¬ prefixeq xs ys ∧ ¬ prefixeq ys xs"
  using assms unfolding parallel_def by blast

theorem prefixeq_cases:
  obtains "prefixeq xs ys" | "prefix ys xs" | "xs \<parallel> ys"
  unfolding parallel_def prefix_def by blast

theorem parallel_decomp:
  "xs \<parallel> ys ==> ∃as b bs c cs. b ≠ c ∧ xs = as @ b # bs ∧ ys = as @ c # cs"
proof (induct xs rule: rev_induct)
  case Nil
  then have False by auto
  then show ?case ..
next
  case (snoc x xs)
  show ?case
  proof (rule prefixeq_cases)
    assume le: "prefixeq xs ys"
    then obtain ys' where ys: "ys = xs @ ys'" ..
    show ?thesis
    proof (cases ys')
      assume "ys' = []"
      then show ?thesis by (metis append_Nil2 parallelE prefixeqI snoc.prems ys)
    next
      fix c cs assume ys': "ys' = c # cs"
      then show ?thesis
        by (metis Cons_eq_appendI eq_Nil_appendI parallelE prefixeqI
          same_prefixeq_prefixeq snoc.prems ys)
    qed
  next
    assume "prefix ys xs"
    then have "prefixeq ys (xs @ [x])" by (simp add: prefix_def)
    with snoc have False by blast
    then show ?thesis ..
  next
    assume "xs \<parallel> ys"
    with snoc obtain as b bs c cs where neq: "(b::'a) ≠ c"
      and xs: "xs = as @ b # bs" and ys: "ys = as @ c # cs"
      by blast
    from xs have "xs @ [x] = as @ b # (bs @ [x])" by simp
    with neq ys show ?thesis by blast
  qed
qed

lemma parallel_append: "a \<parallel> b ==> a @ c \<parallel> b @ d"
  apply (rule parallelI)
    apply (erule parallelE, erule conjE,
      induct rule: not_prefixeq_induct, simp+)+
  done

lemma parallel_appendI: "xs \<parallel> ys ==> x = xs @ xs' ==> y = ys @ ys' ==> x \<parallel> y"
  by (simp add: parallel_append)

lemma parallel_commute: "a \<parallel> b <-> b \<parallel> a"
  unfolding parallel_def by auto


subsection {* Suffix order on lists *}

definition suffixeq :: "'a list => 'a list => bool"
  where "suffixeq xs ys = (∃zs. ys = zs @ xs)"

definition suffix :: "'a list => 'a list => bool"
  where "suffix xs ys <-> (∃us. ys = us @ xs ∧ us ≠ [])"

lemma suffix_imp_suffixeq:
  "suffix xs ys ==> suffixeq xs ys"
  by (auto simp: suffixeq_def suffix_def)

lemma suffixeqI [intro?]: "ys = zs @ xs ==> suffixeq xs ys"
  unfolding suffixeq_def by blast

lemma suffixeqE [elim?]:
  assumes "suffixeq xs ys"
  obtains zs where "ys = zs @ xs"
  using assms unfolding suffixeq_def by blast

lemma suffixeq_refl [iff]: "suffixeq xs xs"
  by (auto simp add: suffixeq_def)
lemma suffix_trans:
  "suffix xs ys ==> suffix ys zs ==> suffix xs zs"
  by (auto simp: suffix_def)
lemma suffixeq_trans: "[|suffixeq xs ys; suffixeq ys zs|] ==> suffixeq xs zs"
  by (auto simp add: suffixeq_def)
lemma suffixeq_antisym: "[|suffixeq xs ys; suffixeq ys xs|] ==> xs = ys"
  by (auto simp add: suffixeq_def)

lemma suffixeq_tl [simp]: "suffixeq (tl xs) xs"
  by (induct xs) (auto simp: suffixeq_def)

lemma suffix_tl [simp]: "xs ≠ [] ==> suffix (tl xs) xs"
  by (induct xs) (auto simp: suffix_def)

lemma Nil_suffixeq [iff]: "suffixeq [] xs"
  by (simp add: suffixeq_def)
lemma suffixeq_Nil [simp]: "(suffixeq xs []) = (xs = [])"
  by (auto simp add: suffixeq_def)

lemma suffixeq_ConsI: "suffixeq xs ys ==> suffixeq xs (y # ys)"
  by (auto simp add: suffixeq_def)
lemma suffixeq_ConsD: "suffixeq (x # xs) ys ==> suffixeq xs ys"
  by (auto simp add: suffixeq_def)

lemma suffixeq_appendI: "suffixeq xs ys ==> suffixeq xs (zs @ ys)"
  by (auto simp add: suffixeq_def)
lemma suffixeq_appendD: "suffixeq (zs @ xs) ys ==> suffixeq xs ys"
  by (auto simp add: suffixeq_def)

lemma suffix_set_subset:
  "suffix xs ys ==> set xs ⊆ set ys" by (auto simp: suffix_def)

lemma suffixeq_set_subset:
  "suffixeq xs ys ==> set xs ⊆ set ys" by (auto simp: suffixeq_def)

lemma suffixeq_ConsD2: "suffixeq (x # xs) (y # ys) ==> suffixeq xs ys"
proof -
  assume "suffixeq (x # xs) (y # ys)"
  then obtain zs where "y # ys = zs @ x # xs" ..
  then show ?thesis
    by (induct zs) (auto intro!: suffixeq_appendI suffixeq_ConsI)
qed

lemma suffixeq_to_prefixeq [code]: "suffixeq xs ys <-> prefixeq (rev xs) (rev ys)"
proof
  assume "suffixeq xs ys"
  then obtain zs where "ys = zs @ xs" ..
  then have "rev ys = rev xs @ rev zs" by simp
  then show "prefixeq (rev xs) (rev ys)" ..
next
  assume "prefixeq (rev xs) (rev ys)"
  then obtain zs where "rev ys = rev xs @ zs" ..
  then have "rev (rev ys) = rev zs @ rev (rev xs)" by simp
  then have "ys = rev zs @ xs" by simp
  then show "suffixeq xs ys" ..
qed

lemma distinct_suffixeq: "distinct ys ==> suffixeq xs ys ==> distinct xs"
  by (clarsimp elim!: suffixeqE)

lemma suffixeq_map: "suffixeq xs ys ==> suffixeq (map f xs) (map f ys)"
  by (auto elim!: suffixeqE intro: suffixeqI)

lemma suffixeq_drop: "suffixeq (drop n as) as"
  unfolding suffixeq_def
  apply (rule exI [where x = "take n as"])
  apply simp
  done

lemma suffixeq_take: "suffixeq xs ys ==> ys = take (length ys - length xs) ys @ xs"
  by (auto elim!: suffixeqE)

lemma suffixeq_suffix_reflclp_conv: "suffixeq = suffix⇧=⇧="
proof (intro ext iffI)
  fix xs ys :: "'a list"
  assume "suffixeq xs ys"
  show "suffix⇧=⇧= xs ys"
  proof
    assume "xs ≠ ys"
    with `suffixeq xs ys` show "suffix xs ys"
      by (auto simp: suffixeq_def suffix_def)
  qed
next
  fix xs ys :: "'a list"
  assume "suffix⇧=⇧= xs ys"
  then show "suffixeq xs ys"
  proof
    assume "suffix xs ys" then show "suffixeq xs ys"
      by (rule suffix_imp_suffixeq)
  next
    assume "xs = ys" then show "suffixeq xs ys"
      by (auto simp: suffixeq_def)
  qed
qed

lemma parallelD1: "x \<parallel> y ==> ¬ prefixeq x y"
  by blast

lemma parallelD2: "x \<parallel> y ==> ¬ prefixeq y x"
  by blast

lemma parallel_Nil1 [simp]: "¬ x \<parallel> []"
  unfolding parallel_def by simp

lemma parallel_Nil2 [simp]: "¬ [] \<parallel> x"
  unfolding parallel_def by simp

lemma Cons_parallelI1: "a ≠ b ==> a # as \<parallel> b # bs"
  by auto

lemma Cons_parallelI2: "[| a = b; as \<parallel> bs |] ==> a # as \<parallel> b # bs"
  by (metis Cons_prefixeq_Cons parallelE parallelI)

lemma not_equal_is_parallel:
  assumes neq: "xs ≠ ys"
    and len: "length xs = length ys"
  shows "xs \<parallel> ys"
  using len neq
proof (induct rule: list_induct2)
  case Nil
  then show ?case by simp
next
  case (Cons a as b bs)
  have ih: "as ≠ bs ==> as \<parallel> bs" by fact
  show ?case
  proof (cases "a = b")
    case True
    then have "as ≠ bs" using Cons by simp
    then show ?thesis by (rule Cons_parallelI2 [OF True ih])
  next
    case False
    then show ?thesis by (rule Cons_parallelI1)
  qed
qed

lemma suffix_reflclp_conv: "suffix⇧=⇧= = suffixeq"
  by (intro ext) (auto simp: suffixeq_def suffix_def)

lemma suffix_lists: "suffix xs ys ==> ys ∈ lists A ==> xs ∈ lists A"
  unfolding suffix_def by auto


subsection {* Homeomorphic embedding on lists *}

inductive list_hembeq :: "('a => 'a => bool) => 'a list => 'a list => bool"
  for P :: "('a => 'a => bool)"
where
  list_hembeq_Nil [intro, simp]: "list_hembeq P [] ys"
| list_hembeq_Cons [intro] : "list_hembeq P xs ys ==> list_hembeq P xs (y#ys)"
| list_hembeq_Cons2 [intro]: "P⇧=⇧= x y ==> list_hembeq P xs ys ==> list_hembeq P (x#xs) (y#ys)"

lemma list_hembeq_Nil2 [simp]:
  assumes "list_hembeq P xs []" shows "xs = []"
  using assms by (cases rule: list_hembeq.cases) auto

lemma list_hembeq_refl [simp, intro!]:
  "list_hembeq P xs xs"
  by (induct xs) auto

lemma list_hembeq_Cons_Nil [simp]: "list_hembeq P (x#xs) [] = False"
proof -
  { assume "list_hembeq P (x#xs) []"
    from list_hembeq_Nil2 [OF this] have False by simp
  } moreover {
    assume False
    then have "list_hembeq P (x#xs) []" by simp
  } ultimately show ?thesis by blast
qed

lemma list_hembeq_append2 [intro]: "list_hembeq P xs ys ==> list_hembeq P xs (zs @ ys)"
  by (induct zs) auto

lemma list_hembeq_prefix [intro]:
  assumes "list_hembeq P xs ys" shows "list_hembeq P xs (ys @ zs)"
  using assms
  by (induct arbitrary: zs) auto

lemma list_hembeq_ConsD:
  assumes "list_hembeq P (x#xs) ys"
  shows "∃us v vs. ys = us @ v # vs ∧ P⇧=⇧= x v ∧ list_hembeq P xs vs"
using assms
proof (induct x ≡ "x # xs" ys arbitrary: x xs)
  case list_hembeq_Cons
  then show ?case by (metis append_Cons)
next
  case (list_hembeq_Cons2 x y xs ys)
  then show ?case by (cases xs) (auto, blast+)
qed

lemma list_hembeq_appendD:
  assumes "list_hembeq P (xs @ ys) zs"
  shows "∃us vs. zs = us @ vs ∧ list_hembeq P xs us ∧ list_hembeq P ys vs"
using assms
proof (induction xs arbitrary: ys zs)
  case Nil then show ?case by auto
next
  case (Cons x xs)
  then obtain us v vs where "zs = us @ v # vs"
    and "P⇧=⇧= x v" and "list_hembeq P (xs @ ys) vs" by (auto dest: list_hembeq_ConsD)
  with Cons show ?case by (metis append_Cons append_assoc list_hembeq_Cons2 list_hembeq_append2)
qed

lemma list_hembeq_suffix:
  assumes "list_hembeq P xs ys" and "suffix ys zs"
  shows "list_hembeq P xs zs"
  using assms(2) and list_hembeq_append2 [OF assms(1)] by (auto simp: suffix_def)

lemma list_hembeq_suffixeq:
  assumes "list_hembeq P xs ys" and "suffixeq ys zs"
  shows "list_hembeq P xs zs"
  using assms and list_hembeq_suffix unfolding suffixeq_suffix_reflclp_conv by auto

lemma list_hembeq_length: "list_hembeq P xs ys ==> length xs ≤ length ys"
  by (induct rule: list_hembeq.induct) auto

lemma list_hembeq_trans:
  assumes "!!x y z. [|x ∈ A; y ∈ A; z ∈ A; P x y; P y z|] ==> P x z"
  shows "!!xs ys zs. [|xs ∈ lists A; ys ∈ lists A; zs ∈ lists A;
    list_hembeq P xs ys; list_hembeq P ys zs|] ==> list_hembeq P xs zs"
proof -
  fix xs ys zs
  assume "list_hembeq P xs ys" and "list_hembeq P ys zs"
    and "xs ∈ lists A" and "ys ∈ lists A" and "zs ∈ lists A"
  then show "list_hembeq P xs zs"
  proof (induction arbitrary: zs)
    case list_hembeq_Nil show ?case by blast
  next
    case (list_hembeq_Cons xs ys y)
    from list_hembeq_ConsD [OF `list_hembeq P (y#ys) zs`] obtain us v vs
      where zs: "zs = us @ v # vs" and "P⇧=⇧= y v" and "list_hembeq P ys vs" by blast
    then have "list_hembeq P ys (v#vs)" by blast
    then have "list_hembeq P ys zs" unfolding zs by (rule list_hembeq_append2)
    from list_hembeq_Cons.IH [OF this] and list_hembeq_Cons.prems show ?case by simp
  next
    case (list_hembeq_Cons2 x y xs ys)
    from list_hembeq_ConsD [OF `list_hembeq P (y#ys) zs`] obtain us v vs
      where zs: "zs = us @ v # vs" and "P⇧=⇧= y v" and "list_hembeq P ys vs" by blast
    with list_hembeq_Cons2 have "list_hembeq P xs vs" by simp
    moreover have "P⇧=⇧= x v"
    proof -
      from zs and `zs ∈ lists A` have "v ∈ A" by auto
      moreover have "x ∈ A" and "y ∈ A" using list_hembeq_Cons2 by simp_all
      ultimately show ?thesis
        using `P⇧=⇧= x y` and `P⇧=⇧= y v` and assms
        by blast
    qed
    ultimately have "list_hembeq P (x#xs) (v#vs)" by blast
    then show ?case unfolding zs by (rule list_hembeq_append2)
  qed
qed


subsection {* Sublists (special case of homeomorphic embedding) *}

abbreviation sublisteq :: "'a list => 'a list => bool"
  where "sublisteq xs ys ≡ list_hembeq (op =) xs ys"

lemma sublisteq_Cons2: "sublisteq xs ys ==> sublisteq (x#xs) (x#ys)" by auto

lemma sublisteq_same_length:
  assumes "sublisteq xs ys" and "length xs = length ys" shows "xs = ys"
  using assms by (induct) (auto dest: list_hembeq_length)

lemma not_sublisteq_length [simp]: "length ys < length xs ==> ¬ sublisteq xs ys"
  by (metis list_hembeq_length linorder_not_less)

lemma [code]:
  "list_hembeq P [] ys <-> True"
  "list_hembeq P (x#xs) [] <-> False"
  by (simp_all)

lemma sublisteq_Cons': "sublisteq (x#xs) ys ==> sublisteq xs ys"
  by (induct xs) (auto dest: list_hembeq_ConsD)

lemma sublisteq_Cons2':
  assumes "sublisteq (x#xs) (x#ys)" shows "sublisteq xs ys"
  using assms by (cases) (rule sublisteq_Cons')

lemma sublisteq_Cons2_neq:
  assumes "sublisteq (x#xs) (y#ys)"
  shows "x ≠ y ==> sublisteq (x#xs) ys"
  using assms by (cases) auto

lemma sublisteq_Cons2_iff [simp, code]:
  "sublisteq (x#xs) (y#ys) = (if x = y then sublisteq xs ys else sublisteq (x#xs) ys)"
  by (metis list_hembeq_Cons sublisteq_Cons2 sublisteq_Cons2' sublisteq_Cons2_neq)

lemma sublisteq_append': "sublisteq (zs @ xs) (zs @ ys) <-> sublisteq xs ys"
  by (induct zs) simp_all

lemma sublisteq_refl [simp, intro!]: "sublisteq xs xs" by (induct xs) simp_all

lemma sublisteq_antisym:
  assumes "sublisteq xs ys" and "sublisteq ys xs"
  shows "xs = ys"
using assms
proof (induct)
  case list_hembeq_Nil
  from list_hembeq_Nil2 [OF this] show ?case by simp
next
  case list_hembeq_Cons2
  then show ?case by simp
next
  case list_hembeq_Cons
  then show ?case
    by (metis sublisteq_Cons' list_hembeq_length Suc_length_conv Suc_n_not_le_n)
qed

lemma sublisteq_trans: "sublisteq xs ys ==> sublisteq ys zs ==> sublisteq xs zs"
  by (rule list_hembeq_trans [of UNIV "op ="]) auto

lemma sublisteq_append_le_same_iff: "sublisteq (xs @ ys) ys <-> xs = []"
  by (auto dest: list_hembeq_length)

lemma list_hembeq_append_mono:
  "[| list_hembeq P xs xs'; list_hembeq P ys ys' |] ==> list_hembeq P (xs@ys) (xs'@ys')"
  apply (induct rule: list_hembeq.induct)
    apply (metis eq_Nil_appendI list_hembeq_append2)
   apply (metis append_Cons list_hembeq_Cons)
  apply (metis append_Cons list_hembeq_Cons2)
  done


subsection {* Appending elements *}

lemma sublisteq_append [simp]:
  "sublisteq (xs @ zs) (ys @ zs) <-> sublisteq xs ys" (is "?l = ?r")
proof
  { fix xs' ys' xs ys zs :: "'a list" assume "sublisteq xs' ys'"
    then have "xs' = xs @ zs & ys' = ys @ zs --> sublisteq xs ys"
    proof (induct arbitrary: xs ys zs)
      case list_hembeq_Nil show ?case by simp
    next
      case (list_hembeq_Cons xs' ys' x)
      { assume "ys=[]" then have ?case using list_hembeq_Cons(1) by auto }
      moreover
      { fix us assume "ys = x#us"
        then have ?case using list_hembeq_Cons(2) by(simp add: list_hembeq.list_hembeq_Cons) }
      ultimately show ?case by (auto simp:Cons_eq_append_conv)
    next
      case (list_hembeq_Cons2 x y xs' ys')
      { assume "xs=[]" then have ?case using list_hembeq_Cons2(1) by auto }
      moreover
      { fix us vs assume "xs=x#us" "ys=x#vs" then have ?case using list_hembeq_Cons2 by auto}
      moreover
      { fix us assume "xs=x#us" "ys=[]" then have ?case using list_hembeq_Cons2(2) by bestsimp }
      ultimately show ?case using `op =⇧=⇧= x y` by (auto simp: Cons_eq_append_conv)
    qed }
  moreover assume ?l
  ultimately show ?r by blast
next
  assume ?r then show ?l by (metis list_hembeq_append_mono sublisteq_refl)
qed

lemma sublisteq_drop_many: "sublisteq xs ys ==> sublisteq xs (zs @ ys)"
  by (induct zs) auto

lemma sublisteq_rev_drop_many: "sublisteq xs ys ==> sublisteq xs (ys @ zs)"
  by (metis append_Nil2 list_hembeq_Nil list_hembeq_append_mono)


subsection {* Relation to standard list operations *}

lemma sublisteq_map:
  assumes "sublisteq xs ys" shows "sublisteq (map f xs) (map f ys)"
  using assms by (induct) auto

lemma sublisteq_filter_left [simp]: "sublisteq (filter P xs) xs"
  by (induct xs) auto

lemma sublisteq_filter [simp]:
  assumes "sublisteq xs ys" shows "sublisteq (filter P xs) (filter P ys)"
  using assms by (induct) auto

lemma "sublisteq xs ys <-> (∃N. xs = sublist ys N)" (is "?L = ?R")
proof
  assume ?L
  then show ?R
  proof (induct)
    case list_hembeq_Nil show ?case by (metis sublist_empty)
  next
    case (list_hembeq_Cons xs ys x)
    then obtain N where "xs = sublist ys N" by blast
    then have "xs = sublist (x#ys) (Suc ` N)"
      by (clarsimp simp add:sublist_Cons inj_image_mem_iff)
    then show ?case by blast
  next
    case (list_hembeq_Cons2 x y xs ys)
    then obtain N where "xs = sublist ys N" by blast
    then have "x#xs = sublist (x#ys) (insert 0 (Suc ` N))"
      by (clarsimp simp add:sublist_Cons inj_image_mem_iff)
    moreover from list_hembeq_Cons2 have "x = y" by simp
    ultimately show ?case by blast
  qed
next
  assume ?R
  then obtain N where "xs = sublist ys N" ..
  moreover have "sublisteq (sublist ys N) ys"
  proof (induct ys arbitrary: N)
    case Nil show ?case by simp
  next
    case Cons then show ?case by (auto simp: sublist_Cons)
  qed
  ultimately show ?L by simp
qed

end